The blackberry playbook simulator doesn't yet include the web browser application, but I found it pretty easy to write my own using the qnx.media.QNXStageWebView class and calling the loadUrl method. This class also has a loadString(code, mimeType) and executeJavaScript method that looks interesting.

Here's the code for a simple browser:

package 
{
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.geom.Rectangle;
	import flash.text.TextField;
	
	import qnx.media.QNXStageWebView;
	import qnx.ui.buttons.LabelButton;
	import qnx.ui.text.TextInput;
	
	// The following metadata specifies the size and properties of the canvas that
	// this application should occupy on the BlackBerry PlayBook screen.
	[SWF(width="1024", height="600", backgroundColor="#cccccc", frameRate="30")]
	public class PlaybookTest extends Sprite
	{
		private var addressInput:TextInput = null;
		private var webView:QNXStageWebView = null;
		public function PlaybookTest()
		{
			addressInput = new TextInput();
			addressInput.x = 10;
			addressInput.y = 10;
			addressInput.text = "http://foundeo.com/";
			
			var goButton:LabelButton = new LabelButton();
			goButton.label = "Go";
			goButton.x = addressInput.width + 10;
			goButton.y = addressInput.y;
			goButton.addEventListener(MouseEvent.CLICK, go);
			
			
			var closeButton:LabelButton = new LabelButton();
			closeButton.label = "Close";		
			closeButton.addEventListener(MouseEvent.CLICK, closeWindow);
			closeButton.x = (stage.stageWidth - closeButton.width) - 10;
			closeButton.y = 10;
			
			webView = new QNXStageWebView(); 
			webView.stage= stage;
			webView.autoFit=true;
			webView.viewPort = new Rectangle(10,100,stage.stageWidth,stage.stageHeight-100);
			webView.enableCookies = true; 
			webView.enableJavascript = true; 
			webView.enableScrolling = true; 
			webView.loadURL("http://foundeo.com");
			
			addChild(addressInput);
				
			addChild(goButton);
			addChild(closeButton);
			
			stage.nativeWindow.visible = true;
		}
		
		private function closeWindow(event:MouseEvent):void{
			stage.nativeWindow.close();
		}
		
		private function go(event:MouseEvent):void {
			webView.loadURL(addressInput.text);
		}
	}
}

Here's a screenshot of the app: